Excel-TippMehr Übersicht in den Excel-Formeln mit der Funktion LET()

Mit der Excel-Funktion LET() vergeben Sie Rechenparametern sprechende Namen. Mit diesen Namen können Sie Rechenformeln definieren, die leicht lesbar und verständlich sind. Zwei Beispiele zeigen, wie Sie LET() einsetzen.

Was leistet die Excel-Funktion LET()?

Die Excel-Funktion LET() ermöglicht Benutzern, komplexe Formeln zu erstellen und gleichzeitig den Code lesbarer und wartbarer zu gestalten. Die LET()-Funktion erlaubt die Definition von benannten Zwischenergebnissen innerhalb einer Formel, was zu einer verbesserten Struktur und Verständlichkeit der Formelcodes führt.

Die wesentlichen Vorteile der LET()-Funktion sind:

Verbesserte Übersichtlichkeit: Die Funktion erlaubt die Zuweisung von Namen zu einzelnen Werten oder ganzen Berechnungen in einer Formel. Dies erleichtert die Lesbarkeit und Verständlichkeit von langen und komplexen Formeln.
Verbesserte Leistung: Durch die Definition von Variablen mit wiederkehrenden Werten oder Berechnungen können diese in der gesamten Formel wiederverwendet werden. Dadurch wird die Leistung verbessert, da bestimmte Berechnungen nur einmal durchgeführt werden müssen.

So ist die LET-Funktion definiert

Die Syntax der LET()-Funktion lautet wie folgt:

=LET(Name1;Wert1;[Name2;Wert2];…;Ausdruck)

Name1, Name2 etc.: Die Namen, die den Zwischenergebnissen (Variablen) zugewiesen werden sollen.
Wert1, Wert2 etc.: Die Werte oder Ausdrücke, die den entsprechenden Variablen zugewiesen werden sollen.
Ausdruck: Der Hauptausdruck, der die berechneten Zwischenergebnisse verwendet.

Ein einfaches Beispiel für die Excel-Funktion LET()

Das folgende Beispiel zeigt die Funktionsweise der LET()-Funktion. Aus einem gegebenen Nettoumsatz und Steuersatz soll die Umsatzsteuer berechnet werden.

In den ersten Argumenten definieren Sie zuerst die Namen (Variablen) und die Herkunft des jeweiligen Wertes, die in der Funktion verwendet werden sollen:

Nettobetrag =LET(Nettobetrag;A2;Steuersatz;B2;Nettobetrag*Steuersatz)
Steuersatz =LET(Nettobetrag;A2;Steuersatz;B2;Nettobetrag*Steuersatz)

Im letzten Argument der Funktion LET() wird dann immer die eigentliche Berechnung durchgeführt. Hier werden die definierten Namen (Variablen) für die Berechnung verwendet.

Berechnung =LET(Nettobetrag;A2;Steuersatz;B2;Nettobetrag*Steuersatz)

Da die definierten Namen nur in der jeweiligen Formel gelten, können Sie die Funktion daher ohne Probleme in andere Zellen kopieren, ohne dass es zu Namenskonflikten in der Arbeitsmappe kommt.

Ein komplexes Beispiel und die Stärke der LET-Funktion

Je komplexer die Formel oder Berechnung, desto mehr kann die Funktion LET() ihre Stärke bezogen auf die verbesserte Übersichtlichkeit ausspielen. Schauen Sie sich das folgende Beispiel an und versuchen Sie, die Formel in der Spalte D schnell zu durchschauen.

Die Aufstellung enthält die Umsätze eines Konzerns nach Filialen, die in unterschiedlichen Kontinenten ansässig sind. Der jeweilige Filialumsatz wird mit dem Durchschnittsumsatz des Kontinents verglichen. Die folgenden Ergebnisse werden dann wie folgt zurückgegeben:

+, wenn der Umsatz größer als der Durchschnittsumsatz des entsprechenden Kontinents ist
-, wenn der Umsatz kleiner als der Durchschnittsumsatz des entsprechenden Kontinents ist
0, wenn der Umsatz gleich dem Durchschnittsumsatz des entsprechenden Kontinents ist

Hätten Sie dies sofort aus der verwendeten Formel herauslesen können?

=WENN(C2>MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);"+";WENN(C2<MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);"-";0))

Vermutlich nicht! Schauen Sie sich die Alternative mit der Funktion LET() an:

Auswertung der Umsatzliste mit der LET-Funktion

In ersten Teil der Funktion LET() werden zuerst die Namen (Variablen) und dann die entsprechenden Werte definiert. Sie teilen der Funktion also mit:

Der Umsatz einer Filiale steht im Feld C2 =LET(Umsatz;C2;Durchschnitt;MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);WENN(Umsatz>Durchschnitt;"+";WENN(Umsatz<Durchschnitt;"-";0)))
Der Durchschnitt der Umsätze pro Kontinent wird mit der Formel MITTELWERTWENNS() berechnet =LET(Umsatz;C2;Durchschnitt;MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);WENN(Umsatz>Durchschnitt;"+";WENN(Umsatz<Durchschnitt;"-";0)))

Am Schluss, im letzten Argument, erfolgt dann die eigentliche Berechnung mit den definierten Namen (Variablen):

Berechnung =LET(Umsatz;C2;Durchschnitt;MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);WENN(Umsatz>Durchschnitt;"+";WENN(Umsatz<Durchschnitt;"-";0)))

Die eigentliche Berechnung in der Funktion LET WENN(Umsatz>Durchschnitt;"+";WENN(Umsatz<Durchschnitt;"-";0)) ist deutlich übersichtlicher und einfacher zu verstehen als die Ausgangsformel mit =WENN(C2>MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);"+";WENN(C2<MITTELWERTWENNS($C$2:$C$21;$A$2:$A$21;A2);"-";0))

Weitere Vereinfachung der Formel mit LET()

Sie können das Ganze mit LET() gliedern und somit übersichtlicher gestalten, wenn Sie auch die Argumente für die Funktion MITTELWERTWENNS() mit Namen in der Funktion LET() versehen:

=LET(Regionbereich;$A$2:$A$21;Region;A2;Umsatzbereich;$C$2:$C$21;Umsatz;C2;Durchschnitt;MITTELWERTWENNS(Umsatzbereich;Regionbereich;Region);WENN(Umsatz>Durchschnitt;"+";WENN(Umsatz<Durchschnitt;"-";0)))

Dieses Beispiel zeigt, dass auch Zellbereiche als Parameter definiert werden können: Regionbereich;$A$2:$A$21

Verkettung von Parametern mit der Funktion LET()

Hinweis: Nach ein paar Anwendungen definieren und lesen Sie viel schneller die Rechenregel mit der LET-Funktion. Probieren Sie es aus!